Release 2012.12.16.00

This release includes a few new EZ-Script commands for file operations and GUI enhancements.

• EZ-Script Edit Window now saves the size of the window you resize to

• Examples Menu has easier to read buttons

• New EZ-Script File Operations (FileReadClose, FileReadReset, FileExists, FileReadEnd, FileReadChar, FileReadLine, FileReadAll)

• New EZ-Script function for splitting string into fields - Split()

• Speech Recognition Control includes Audio Level Graph

The File Operations Example Project will demonstrate how to perform EZ-Script File Operations for Reading, Writing and Parsing. Choose Examples and select the File Operations project.

File Operation Example Project

New Speech Recognition Control with Audio Level

File Write Example

# This  EZ-Script will log the positions of 
# servos D3 and D4 in the specified file. 
# The loop will repeat 10 times for 10 seconds

$filename = "c:\temp\myfile.txt"

FileDelete($filename)

$cnt = 0
$max = 10

:START

  print("Writing line $cnt or $max")

  FileWrite($filename, "Time: $time")
  FileWrite($filename, ", Left Servo: GetServo(d3)")
  FileWriteLine($filename, ", Right Servo: GetServo(d4)")

  $cnt = $cnt + 1

  if ($cnt = $max)
    halt()

  sleep(1000)

goto(START)

File Read Example

$filename = "c:\temp\myfile.txt"

if (FileExists($filename) = false)
  print("File does not exist")
  Halt()
Endif

FileReadReset($filename)

:START

  $txt = FileReadLine($filename)

  print("Read: $txt")

  if (FileReadEnd($filename) = true)
    print("End Of File")
    halt()
  endif

goto(START)

File Read with Splitting Fields By Coma Seperator Using SPLIT() Function

# Reads a file and seperates each field by a comma.
# The Split() function will return a
# specified field index

$filename = "c:\temp\myfile.txt"

if (FileExists($filename) = false)
  print("File does not exist")
  Halt()
Endif

FileReadReset($filename)

$cnt = 1

:START

  $txt = FileReadLine($filename)

  $DateField = Split($txt, ",", 0)
  $LeftArmField = Split($txt, ",", 1)
  $RightArmField = Split($txt, ",", 2)

  print("Row: $cnt")
  print("Date: $DateField")
  print("Left Arm: $LeftArmField")
  print("Right Arm: $RightArmField")
  print()

  if (FileReadEnd($filename) = true)
    print("End Of File")
    halt()
  endif

  $cnt = $cnt + 1
goto(START)

SPLIT() Example #1

$x="one, two, three"

$first=split($x, ",", 0)
$second=split($x, ",", 1)

print("First Field is: $first")
print("Second Field is: $second")

SPLIT() Example #2

$x="one - two - three"

$first=split($x, "-", 0)
$second=split($x, "-", 1)

print("First Field is: $first")
print("Second Field is: $second")